websocketd/src/websocketd-dev.cr

require "option_parser"
require "ipc"
require "socket"
require "./colors"

require "colorize"

require "json"

require "socket"
require "http/server"
require "base64"
require "digest"
require "./utils"

require "baguette-crystal-base"

require "./instance_storage.cr"

# All modifications to standard libraries go there.
require "./lib_modifications.cr"

class Context
	# service instance parameters
	# they can be changed via the cli
	class_property service_name   : String = "websocket"
	class_property host           : String = "0.0.0.0"
	class_property port_to_listen : UInt16 = 1234
	class_property timer_delay    : Int32  = 30_000  # 30 seconds
end

OptionParser.parse do |parser|
	parser.on "-l host", "--l host", "IP address to listen on." do |h|
		Context.host = h
	end

	parser.on "-p port", "--port port", "Port to listen on." do |port|
		Context.port_to_listen = port.to_u16
	end

	parser.on "-s service-name", "--service-name service-name", "Service name." do |name|
		Context.service_name = name
	end

	parser.on "-t timer-delay", "--timer-delay timer-delay", "Timer delay (in seconds)" do |t|
		Context.timer_delay = t.to_i32 * 1000 # stored in ms
	end

	parser.on "-v verbosity-level", "--verbosity level", "Verbosity." do |opt|
		Baguette::Context.verbosity = opt.to_i
	end

	parser.on "-h", "--help", "Show this help" do
		puts parser
		exit 0
	end
end

def sending_ping_messages
	Context.context.fd_to_websocket.each do |fd, ws|
		begin
			ws.ping "hello from #{fd}"
		rescue e
			Baguette::Log.error "Exception: #{e}, already closed client #{fd}"
			begin
				Context.context.remove_fd fd
			rescue e
				Baguette::Log.error "Cannot remove #{fd} from clients: #{e}"
			end
		end
	end
end

def ws_http_upgrade(client)
	request = HTTP::Request.from_io client

	if request.nil?
		raise "#REQUEST IS NIL"
	end

	if request.is_a? HTTP::Status && request == HTTP::Status::BAD_REQUEST
		raise "BAD REQUEST DAZE~"
	end

	if request.is_a? HTTP::Status
		raise "Not bad request but still pretty bad: #{request.to_s}"
	end

	# FIXME: check they actually wanted to upgrade to websocket
	key = request.headers["Sec-WebSocket-Key"]
	response_key = Digest::SHA1.base64digest key + "258EAFA5-E914-47DA-95CA-C5AB0DC85B11"
	# Baguette::Log.debug response_key

	# HTTP inside bru
	headers_header = "HTTP/1.1 101 Switching Protocols"
	headers = HTTP::Headers {
		"Upgrade" => "websocket",
		"Connection" => "Upgrade",
		"Sec-WebSocket-Accept" => response_key
	}

	headers = headers.map { |key, value| "#{key}: #{value[0]}\r\n" }.join

	# requested service, fd
	req_service = request.path.lchop.sub "ws/", ""

	if req_service.ends_with? ".JSON"
		Context.context.is_json[client.fd] = true
		req_service = req_service.gsub /.JSON$/, ""
	else
		Context.context.is_json[client.fd] = false
	end

	# puts "#{headers_header}\n#{headers.to_s}\r\n"
	client.send "#{headers_header}\n#{headers.to_s}\r\n"

	wsclient = WebSocket.new client
	wsclient.on_pong do |m|
		Baguette::Log.debug "pong #{m}"
	end

	# registering the client into storing structures to avoid being garbage collected
	Context.context.fd_to_socket[client.fd]    = client
	Context.context.fd_to_websocket[client.fd] = wsclient

	return req_service, request
rescue e
	Baguette::Log.error "Exception in ws_http_upgrade: #{e}"
	raise "DROP IT"
end

def handle_new_clients(service, server)
	# TODO: this is a lot of C-like notation, should be changed.
	# In the client accept function
	#   1. accept TCP/WS connection
	client = server.accept

	#   2. upgrade HTTP connections and get the service name in the URI path.
	req_service, request = ws_http_upgrade client

	#   3. connect to the service via ipc_connection_switched
	serverfd : Int32 = 0
	# LibIPC.ipc_connection_switched service.pointer, req_service, client.fd, Pointer(Libc::Int).null
	spointer = pointerof(serverfd)
	if req_service == "tracker"
		req_service = "tracking"
	end
	LibIPC.ipc_connection_switched service.pointer, req_service, client.fd, spointer
	if serverfd == 0
		raise "Could not connect to #{req_service}"
	end

	#   4. change client callbacks via ipc_switching_callbacks
	#      only the client callbacks are changed, since the associated server is a simple libipc service
	proc_cb_in  = ->ws_cb_in(Int32, Pointer(LibIPC::Message), Int16*)
	proc_cb_out = ->ws_cb_out(Int32, Pointer(LibIPC::Message))

	LibIPC.ipc_switching_callbacks service.pointer, client.fd, proc_cb_in, proc_cb_out

	#   5. In case the requested service is trackingd,
	#      the websocketd has to provide the IP address as the first message.
	if req_service == "tracking"
		# The proxy is configured to provide the X-Real-IP in the headers.
		# If not found, we use the client address from the socket.
		real_ip_address = request.headers["X-Real-IP"] || client.remote_address.address

		Baguette::Log.info "trackingd - sending the IP address #{real_ip_address} to fd #{serverfd}"
		# sfd = Context.context.switchtable[client.fd]
		# message = IPC::Message.from_json(JSON).to_packet
		# => JSON has to include these attributes: mtype, utype, payload
		# message = IPC::Message.new mtype, utype, payload
		# remote_address = client.remote_address.address
		message = IPC::Message.new serverfd, 1, 1.to_u8, "{\"ipaddress\": \"#{real_ip_address}\"}"
		service.send message
		# serv = WrappedTCPFileDescriptor.new(fd: serverfd, family: Socket::Family::INET)
		# serv.send message.to_packet
	end

	Baguette::Log.debug "new client: #{client.fd}"
rescue e
	Baguette::Log.error "Exception in handle_new_client: #{e}"
	unless client.nil?
		client.close
	end
end

def ws_cb_out(fd : Int32, pm : Pointer(LibIPC::Message))
	# Baguette::Log.info "OUT fd is #{fd}"
	wsclient = Context.context.fd_to_websocket[fd]

	message = IPC::Message.new pm
	# pp! message

	if Context.context.is_json[fd]
		buf = message.to_json
	else
		buf = message.to_packet
	end

	wsclient.send buf

	return LibIPC::IPCCB::NoError
rescue e
	Baguette::Log.error "Exception during message transfer: #{e}"
	Context.context.remove_fd fd
	return LibIPC::IPCCB::Error
end

def ws_cb_in(fd : Int32, pm : LibIPC::Message*, more_to_read : Int16*)
	# Baguette::Log.debug "IN fd is #{fd}"

	wsclient = Context.context.fd_to_websocket[fd]

	message = nil
	begin
		message = wsclient.run_once
	rescue e
		Baguette::Log.error "run_once FAILED: #{e}"
		Context.context.remove_fd fd
		return LibIPC::IPCCB::Error
	end

	if wsclient.ws.io.empty?
		more_to_read[0] = 0
	else
		more_to_read[0] = 1
	end

	if wsclient.closed?
		Baguette::Log.info "client closed the connection"
		Context.context.remove_fd fd
		return LibIPC::IPCCB::Closing
	end

	if message.nil?
		Baguette::Log.error "Reveiced a nil message"
		Context.context.remove_fd fd
		return LibIPC::IPCCB::Closing
	end

	case message
	when String
		if Context.context.is_json[fd]
			ipc_message = IPC::Message.from_json(message)
			ipc_message.copy_to_message_pointer pm
			return LibIPC::IPCCB::NoError
		end
	else
		# every other option should be dropped
		case message
		when WebSocket::Error
			Baguette::Log.error "An error occured"
			Context.context.remove_fd fd
			return LibIPC::IPCCB::Error
		when WebSocket::Ping
			Baguette::Log.debug "Received a ping message"
			Context.context.remove_fd fd
			return LibIPC::IPCCB::Ignore
		when WebSocket::Pong
			Baguette::Log.debug "Received a pong message"
			return LibIPC::IPCCB::Ignore
		when WebSocket::Close
			Baguette::Log.debug "Received a close message"
			Context.context.remove_fd fd
			return LibIPC::IPCCB::Closing
		when WebSocket::NotFinal
			Baguette::Log.warning "Received only part of a message: NOT IMPLEMENTED"
			Context.context.remove_fd fd
			return LibIPC::IPCCB::Error
		when Bytes
			# TODO: when receiving a binary message
			# we should test the format and maybe its content
			Baguette::Log.error "Received a binary message: NOT IMPLEMENTED, YET"
			Context.context.remove_fd fd
			return LibIPC::IPCCB::Error
		else
			Baguette::Log.error "Received a websocket message with unknown type"
		end
	end

	return LibIPC::IPCCB::Error

rescue e
	Baguette::Log.error "Exception (receiving a message) #{e}"
	# tcp = WrappedTCPFileDescriptor.new(fd: fd, family: Socket::Family::INET)
	# tcp.close
	Context.context.remove_fd fd
	return LibIPC::IPCCB::Error
end

class Context
	class_property context = InstanceStorage.new
end

def main
	# by default, listen on any IP address
	server  = TCPServer.new(Context.host, Context.port_to_listen)
	service = IPC::Server.new Context.service_name
	service << server.fd

	# Every few seconds, the service should trigger the timer
	# Allowing the sending of Ping messages to clients
	service.base_timer = Context.timer_delay
	service.timer      = Context.timer_delay

	service.loop do |event|
		# Baguette::Log.info "current state of the context:"
		# service.pp
		case event
		when IPC::Event::Timer
			Baguette::Log.debug "IPC::Event::Timer"
			sending_ping_messages

		when IPC::Event::Connection
			Baguette::Log.debug "IPC::Event::Connection: fd #{event.fd}"

		when IPC::Event::Disconnection
			Baguette::Log.debug "IPC::Event::Disconnection: fd #{event.fd}"
			Context.context.remove_fd event.fd

		when IPC::Event::ExtraSocket
			Baguette::Log.debug "IPC::Event::ExtraSocket: fd #{event.fd}"
			if server.fd != event.fd
				raise "Error: the only extra socket should be the TCP/WS server"
			end
			handle_new_clients(service, server)

		when IPC::Event::Switch
			Baguette::Log.debug "IPC::Event::Switch: fd #{event.fd}"
			# raise "Not implemented."

		when IPC::Event::MessageSent
			Baguette::Log.debug "IPC::Event::MessageSent: fd #{event.fd}"

		when IPC::Event::MessageReceived
			Baguette::Log.debug "IPC::Event::Message: fd #{event.fd}"

			raise "Not implemented."
		end
	end
end

main