h     = require 'maquette' .h
bulma = require "./bulma.ls"
Task  = require "./task.ls"
Modal = require './modal.ls'
TaskCreationModal = require './task-creation-modal.ls'

Project = (self, todod-ws) ->
	self.todod-ws = todod-ws
	self.tasks = []

	modal = void

	self.render-column = (column, first) ->
		tasks-to-display = self.tasks.filter (task) ->
			task.extra_properties && task.extra_properties.column && task.extra_properties.column == column.id
			|| ((! task.extra_properties || ! task.extra_properties.column) && first)

		h \div.column [
			bulma.title 4 column.title
			for task in tasks-to-display
				task.render!
		]

	self.render = ->

		# console.log "Project to render: ", self
		h \div.project {} [

			h \div.navbar [

				h \div.navbar-brand [
					h \div.navbar-item [
						self.title
					]
				]

				h \div.navbar-end [
					h \div.navbar-item [
						h \div.button.is-success.is-outlined {
							onclick: ->
								modal := TaskCreationModal self.id, self.todod-ws
						} [ "+" ]
					]

					h \div.navbar-item [
						h \div.button.is-danger.is-outlined {
							onclick: ->
								modal := Modal {
									+visible
									content:
										h \p [ "Are you sure you want to remove board #{self.title}?" ]
									on-validation: ->
										self.todod-ws.remove-list self.id
								}
						} [ "X" ]
					]
				]
			]

			h \div.columns [
				if columns = self.extra_properties.columns
					for dom in columns.map((column, index) -> self.render-column(column, index == 0))
						dom
			]

			if modal
				modal.render!
		]

	self

module.exports = Project