todo-webclient/client/project.ls

h     = require 'maquette' .h
bulma = require "./bulma.ls"
Task  = require "./task.ls"
Modal = require './modal.ls'
TaskCreationModal    = require './task-creation-modal.ls'
ProjectCreationModal = require './project-creation-modal.ls'
ColumnEditModal      = require './column-edit-modal.ls'

{icon} = require './font-awesome.ls'

deep-copy = (object) ->
	JSON.parse JSON.stringify object

is-right-column = (task, column-id) ->
	task.extra_properties && task.extra_properties.column && task.extra_properties.column == column-id

has-column = (task) ->
	task.extra_properties && task.extra_properties.column

# configured column, but inexistant (maybe removed since)
inexistant-column = (task, columns) ->
	columns.filter((.id == task.extra_properties.column)).length == 0

orphan-tasks = (tasks, columns) ->
	tasks.filter (task) -> (! has-column) || inexistant-column task, columns


Project = (self, todod-ws, users) ->
	self.todod-ws = todod-ws
	self.tasks = []
	self.users = users || []

	self.selected-task-id = void

	modal = void

	self.render-column = (column, first) ->

		tasks-to-display = self.tasks.filter (task) -> is-right-column task, column.id

		if first
			tasks-to-display ++= orphan-tasks self.tasks, self.extra_properties.columns

		#
		# COLUMNS
		#

		h \div.column.cards-list {
			key: column.id
		} [
			h \p.title.is-4 [
				column.title

				h \a.is-pulled-right.icon.has-text-grey {
					onclick: ->
						modal := ColumnEditModal self, column, {
							on-validation: (column) ->
								console.log "column update:", column
								modal.visible := false

								extra_properties = deep-copy(self.extra_properties)
								extra_properties.columns = extra_properties.columns.map (old-column) ->
									if old-column.id == column.id
										column
									else
										old-column

								todod-ws.edit-list self.id, {
									extra_properties: extra_properties
								}
						}
				} [
					icon \cog
				]
			]

			tasks-to-display.map (task) ->
				task.render {
					is-selected: (task.id == self.selected-task-id)
					onclick: ->
						if self.selected-task-id == task.id
							self.selected-task-id := void
						else
							self.selected-task-id := task.id
				}
		]

	self.inner-nav-render = ->
		h \div.navbar-item [ h \a.subtitle.is-3 [ self.title ] ]

	self.right-nav-render = ->
		[
			h \a.navbar-item.has-text-success {
				key: "navbar-new-task"
				onclick: ->
					modal := TaskCreationModal self, self.todod-ws, void, self.users
			} [
				h \span [ "New task" ]

				icon \plus
			]

			h \a.navbar-item {
				key: "navbar-edit-project"
				onclick: ->
					modal := ProjectCreationModal {
						project: self

						on-validation: (project) ->
							console.log "Requesting edit for", project
							self.todod-ws.edit-list project.id, project
					}
			} [
				icon \cog
				# "Edit this project"
			]

			h \a.navbar-item.has-text-danger {
				key: "navbar-delete-project"
				onclick: ->
					modal := Modal {
						+visible
						content:
							h \p [ "Are you sure you want to remove board #{self.title}?" ]
						on-validation: ->
							self.todod-ws.remove-list self.id
					}
			} [
				icon \skull-crossbones
				# "Delete this project" 
			]
		]

	self.render = ->

		h \div.project {} [

			h \div.columns [
				if columns = self.extra_properties.columns
					for column in columns
						is-last = column == columns[columns.length-1]

						if is-last
							self.render-column column, is-last
						else
							[
								self.render-column column, is-last
								h \div.is-divider-vertical
							]
			]

			if modal
				modal.render!
		]

	self

module.exports = Project