todo-webclient/client/task-creation-modal.ls

h = require 'maquette' .h
Modal = require './modal.ls'

TaskCreationModal = (project, todod-ws, task) ->
	task ||= {}

	# copy not to override anything on cancel
	self = {
		title: task.title || ""
		description: task.description || ""
		extra_properties: {
			column: ""
		}
	}

	if task.extra_properties && task.extra_properties.column
		self.extra_properties.column = task.extra_properties.column

	modal = Modal {
		+visible
		content-render: (self) ->
			h \div.form [
				h \input.input {
					value: self.title
					oninput: (e) ->
						self.title := e.target.value
				}

				h \textarea {
					value: self.description
					oninput: (e) ->
						self.description := e.target.value
				}

				h \aside.menu [
					h \p.menu-label [ "Choose the column" ]
					h \ul.menu-list project.extra_properties.columns.map (column) ->

						h \li {
							classes: {
								is-active: self.extra_properties && self.extra_properties.column == column.id
							}
						} [
							h \a {
								onclick: ->
									self.extra_properties.column := column.id
							} [ column.title ]
						]
				]
			]

		on-validation: ->
			if task.id
				todod-ws.edit-task task.id, self
			else
				todod-ws.add-task project.id, self.title, self
	}, self

	self.render = ->
		modal.render!

	self

module.exports = TaskCreationModal