authd/src/authd/client.cr

require "ipc/json"
require "json"

module AuthD
	class Client < IPC
		property server_fd : Int32 = -1

		def initialize
			super
			fd = self.connect "auth"
			if fd.nil?
				raise "couldn't connect to 'auth' IPC service"
			end
			@server_fd = fd
		end

		def read
			slice = self.read @server_fd
			m = IPCMessage::TypedMessage.deserialize slice
			m.not_nil!
		end

		# TODO: parse_message should raise exception if response not anticipated
		def parse_message(expected_messages, message)
			em = Array(IPC::JSON.class).new
			expected_messages.each do |e|
				em << e
			end
			# response = AuthD.responses.parse_ipc_json read
			em.parse_ipc_json message
		end

		def login?(login : String, password : String)
			send_now Request::Login.new login, password
			parse_message [Response::Login], read
		end

		def get_user?(login : String, password : String)
			send_now Request::GetUserByCredentials.new login, password
			parse_message [Response::User], read
		end

		def get_user?(uid_or_login : UserID)
			send_now Request::GetUser.new uid_or_login
			parse_message [Response::User], read
		end

		def send_now(msg : IPC::JSON)
			m = IPCMessage::TypedMessage.new msg.type.to_u8, msg.to_json
			write @server_fd, m
		end

		def send_now(type : Request::Type, payload)
			m = IPCMessage::TypedMessage.new type.value.to_u8, payload
			write @server_fd, m
		end

		# FIXME: Extra options may be useful to implement here.
		def add_user(login : String, password : String,
			admin : Bool,
			email : String?,
			profile : Hash(String, ::JSON::Any)?)

			send_now Request::AddUser.new login, password, admin, email, profile
			parse_message [Response::UserAdded], read
		end

		def bootstrap(login : String,
		              password : String,
		              email : String,
		              profile : Hash(String, ::JSON::Any)? = nil)

			send_now Request::BootstrapFirstAdmin.new login, password, email, profile
			parse_message [Response::UserAdded], read
		end

		def decode_token(token)
			send_now Request::DecodeToken.new token
			parse_message [Response::User], read
		end

		def validate_user(login : String, activation_key : String)
			send_now Request::ValidateUser.new login, activation_key
			parse_message [Response::UserValidated], read
		end

		def ask_password_recovery(uid_or_login : UserID)
			send_now Request::AskPasswordRecovery.new uid_or_login
			parse_message [Response::PasswordRecoverySent], read
		end

		def change_password(uid_or_login : UserID, new_pass : String, renew_key : String)
			send_now Request::PasswordRecovery.new uid_or_login, renew_key, new_pass
			parse_message [Response::PasswordRecovered], read
		end

		def register(login : String,
			password : String,
			email : String?,
			profile : Hash(String, ::JSON::Any)?)

			send_now Request::Register.new login, password, email, profile
			parse_message [Response::UserAdded,
			               Response::ErrorRegistrationsClosed,
			               Response::ErrorAlreadyUsedLogin,
			               Response::ErrorInvalidLoginFormat,
			               Response::ErrorMailRequired,
			               Response::ErrorInvalidEmailFormat,
			               Response::ErrorCannotContactUser,
			               Response::ErrorPasswordTooShort], read
		end

		def mod_user(uid_or_login : UserID, password : String? = nil, email : String? = nil)
			request = Request::ModUser.new uid_or_login

			request.password = password if password
			request.email    = email    if email

			send_now request
			parse_message [Response::UserEdited], read
		end

		def check_permission(user : UserID, service_name : String, resource_name : String)
			request = Request::CheckPermission.new user, service_name, resource_name
			send_now request
			parse_message [Response::PermissionCheck], read
		end

		def set_permission(user : UserID, service : String, resource : String, permission : User::PermissionLevel)
			request = Request::SetPermission.new user, service, resource, permission
			send_now request
			parse_message [Response::PermissionSet], read
		end

		def search_user(user_login : String)
			send_now Request::SearchUser.new user_login
			parse_message [Response::MatchingUsers], read
		end

		def edit_profile_content(user : UserID, new_values)
			send_now Request::EditProfileEntries.new user, new_values
			parse_message [Response::User], read
		end

		def delete(user : UserID)
			send_now Request::Delete.new user
			parse_message [Response::UserDeleted], read
		end
	end
end